nfdi-landscape

There are 26 accepted consortia in the German National Research Data Infrastructure (NFDI). The following query to Wikidata gets information about each:

SELECT 
  ?consortium ?consortiumLabel ?ror ?inception ?logo ?chairperson ?chairpersonLabel
  ?website ?youtube ?nfdi4culture ?zenodo
WHERE {
  ?consortium wdt:P361 wd:Q61658497;
              wdt:P31 wd:Q98270496 .
  OPTIONAL { ?consortium wdt:P571 ?inception . }
  OPTIONAL { ?consortium wdt:P154 ?logo . }
  OPTIONAL { 
    ?consortium p:P488 ?statement.
    ?statement ps:P488 ?chairperson.
    # Filter: only current chairperson (no end date)
    FILTER NOT EXISTS { ?statement pq:P582 ?endtime . }
  }
  OPTIONAL { ?consortium wdt:P856 ?website . }
  #OPTIONAL { ?consortium wdt:P2037 ?github . }
  #OPTIONAL { ?consortium wdt:P4033 ?mastodon . }
  OPTIONAL { ?consortium wdt:P6782 ?ror . }
  OPTIONAL { ?consortium wdt:P11971 ?nfdi4culture . }
  OPTIONAL { ?consortium wdt:P2397 ?youtube . }
  OPTIONAL { ?consortium wdt:P9934 ?zenodo . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". } # Helps get the label in your language, if not, then default for all languages, then en language
}
ORDER BY ?consortiumLabel

Relations

I’ve observed two kinds of relations on NFDI Wikidata pages so far: partnerships (P2652) and affiliations (P1416). Partnership relations appear to be unqualified, and affiliations are annotated with object roles. Here’s a query over partnerships, which I’ve loosened from NFDI consortia to any parts of NFDI, which includes other components like arthistoricum.net:

SELECT  ?consortium ?consortiumLabel ?consortiumROR ?partner ?partnerLabel ?partnerROR
WHERE {
  ?consortium wdt:P361+ wd:Q61658497 ;
              wdt:P2652 ?partner .
  OPTIONAL { ?consortium wdt:P6782 ?consortiumROR . }
  OPTIONAL { ?partner wdt:P6782 ?partnerROR . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
ORDER BY ?consortiumLabel ?partnerLabel

The next query gets affiliations from NFDI parts to any external entities (and their ROR IDs, when available):

SELECT ?consortium ?consortiumLabel ?consortiumROR ?affiliate ?affiliateLabel ?affiliateROR ?affiliateRole ?affiliateRoleLabel
WHERE {
  ?consortium wdt:P361+ wd:Q61658497 ;
              p:P1416 ?affiliateStatement .
              
  ?affiliateStatement ps:P1416 ?affiliate .
  
  OPTIONAL { ?affiliateStatement pq:P3831 ?affiliateRole . }
  OPTIONAL { ?consortium wdt:P6782 ?consortiumROR . }
  OPTIONAL { ?affiliate wdt:P6782 ?affiliateROR . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
ORDER BY ?consortiumLabel ?affiliateLabel ?affiliateRoleLabel

I wrote a follow-up SPARQL query over affiliations in Wikidata to understand what kinds of values are used as the object role. This is helpful as a starting point to build a data model with a controlled vocabulary:

SELECT ?role ?roleLabel (COUNT(?role) as ?count)
WHERE {
  ?x p:P1416/pq:P3831 ?role .  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}
GROUP BY ?role ?roleLabel
ORDER BY DESC(?count)